source: SMSSender/smssender.pri @ 407:eeafe5a2e10f

3.2
Last change on this file since 407:eeafe5a2e10f was 407:eeafe5a2e10f, checked in by Sämy Zehnder <saemy.zehnder@…>, 6 years ago
  • Changes version to 'release'.
File size: 1.5 KB
Line 
1# This file gets included twice. Once by the base- and the second time by the
2# frontend library. Therefore, always use *= and only add stuff that a) is
3# valid for all libraries and b) does not overwrite stuff defined in the base
4# library project files (e.g. QT = "" does belong into smssender-gui.pri and not
5# here).
6#
7# The typical include hierarchy could be:
8#   my-gateway-gui.pro
9#     +-> gateways-gui.pri
10#       +-> smssender-gui.pri
11#         +-> smssender.pri     (1)
12#           +-> smssender.prf
13#       +-> gateways.pri
14#     +-> my-gateway-base.pro (with post-processing)
15#       +-> smssender-base.pri
16#         +-> smssender.pri     (2)
17#           +-> smssender.prf
18include(smssender.prf)
19
20BASE_VERSION = 3.2
21
22DEVELOPMENT_VERSION = 3 # 0=alpha; 1=beta; 2=rc; 3=release
23VERSION_REVISION = 0
24
25VERSION = $${BASE_VERSION}.$${DEVELOPMENT_VERSION}.$${VERSION_REVISION}
26
27QMAKE_CXXFLAGS *= \
28    -shared-libgcc \
29    -std=c++11 # replace this by CONFIG += c++11 in Qt5
30QMAKE_CXXFLAGS_DEBUG *= -gdwarf-2 -g3
31QMAKE_LFLAGS += -fvisibility=hidden
32
33INCLUDEPATH *= $$PWD
34
35LIB_SUFFIX=
36EXT_STATICLIB=a
37EXT_DYNAMICLIB=so
38win32 {
39    VERSIONS = $$split(BASE_VERSION, ".")
40    LIB_SUFFIX = $$member(VERSIONS, 0)
41    EXT_DYNAMICLIB=dll
42}
43
44unix {
45    # Search path for libraries
46    CONFIG(debug, debug|release): QMAKE_RPATHDIR *= lib
47    CONFIG(release, debug|release): QMAKE_RPATHDIR *= /usr/lib/smssender
48}
49
50TRANSLATIONS *= \
51    locale/de.ts \
52    locale/de_CH.ts \
53    locale/fr.ts \
54    locale/it.ts
Note: See TracBrowser for help on using the repository browser.