source: SMSSender/smssender.pri @ 419:0bafa60e1b64

Last change on this file since 419:0bafa60e1b64 was 419:0bafa60e1b64, checked in by Sämy Zehnder <saemy.zehnder@…>, 6 years ago
  • Fixes PRE_TARGETDEPS entries for windows.
  • Excapes '\' in project files on windows.
File size: 1.5 KB
Line 
1# This file gets included twice. Once by the base- and the second time by the
2# frontend library. Therefore, always use *= and only add stuff that a) is
3# valid for all libraries and b) does not overwrite stuff defined in the base
4# library project files (e.g. QT = "" does belong into smssender-gui.pri and not
5# here).
6#
7# The typical include hierarchy could be:
8#   my-gateway-gui.pro
9#     +-> gateways-gui.pri
10#       +-> smssender-gui.pri
11#         +-> smssender.pri     (1)
12#           +-> smssender.prf
13#       +-> gateways.pri
14#     +-> my-gateway-base.pro (with post-processing)
15#       +-> smssender-base.pri
16#         +-> smssender.pri     (2)
17#           +-> smssender.prf
18include(smssender.prf)
19
20BASE_VERSION = 3.2
21
22DEVELOPMENT_VERSION = 3 # 0=alpha; 1=beta; 2=rc; 3=release
23VERSION_REVISION = 0
24
25VERSION = $${BASE_VERSION}.$${DEVELOPMENT_VERSION}.$${VERSION_REVISION}
26
27QMAKE_CXXFLAGS *= \
28    -shared-libgcc \
29    -std=c++11 # replace this by CONFIG += c++11 in Qt5
30QMAKE_CXXFLAGS_DEBUG *= -gdwarf-2 -g3
31QMAKE_LFLAGS += -fvisibility=hidden
32
33INCLUDEPATH *= $$PWD
34
35LIB_PREFIX=lib
36LIB_SUFFIX=
37EXT_STATICLIB=a
38EXT_DYNAMICLIB=so
39win32 {
40    VERSIONS = $$split(BASE_VERSION, ".")
41    LIB_PREFIX =
42    LIB_SUFFIX = $$member(VERSIONS, 0)
43    EXT_DYNAMICLIB=dll
44       
45        CONFIG -= console
46}
47
48unix {
49    # Search path for libraries
50    CONFIG(debug, debug|release): QMAKE_RPATHDIR *= lib
51    CONFIG(release, debug|release): QMAKE_RPATHDIR *= /usr/lib/smssender
52}
53
54TRANSLATIONS *= \
55    locale/de.ts \
56    locale/de_CH.ts \
57    locale/fr.ts \
58    locale/it.ts
Note: See TracBrowser for help on using the repository browser.