source: SMSSender/smssender.pri @ 424:21b6e6fc22ab

Last change on this file since 424:21b6e6fc22ab was 424:21b6e6fc22ab, checked in by Sämy Zehnder <saemy.zehnder@…>, 6 years ago
  • Changes the way we handle version strings (no more numeric representations of alpha, beta, ...).
  • Updates the ubuntu deployment script to follow the version changes.
  • Changes the version to 3.2.1
File size: 1.6 KB
Line 
1# This file gets included twice. Once by the base- and the second time by the
2# frontend library. Therefore, always use *= and only add stuff that a) is
3# valid for all libraries and b) does not overwrite stuff defined in the base
4# library project files (e.g. QT = "" does belong into smssender-gui.pri and not
5# here).
6#
7# The typical include hierarchy could be:
8#   my-gateway-gui.pro
9#     +-> gateways-gui.pri
10#       +-> smssender-gui.pri
11#         +-> smssender.pri     (1)
12#           +-> smssender.prf
13#       +-> gateways.pri
14#     +-> my-gateway-base.pro (with post-processing)
15#       +-> smssender-base.pri
16#         +-> smssender.pri     (2)
17#           +-> smssender.prf
18include(smssender.prf)
19
20VERSION = 3.2.1 # Always of the form major.minor.patch (e.g. 3.2.0)
21DEVELOPMENT_VERSION = # alpha1, beta0, rc2 (empty for release)
22
23FULL_VERSION=$$VERSION
24!isEmpty(DEVELOPMENT_VERSION) {
25    FULL_VERSION=$${FULL_VERSION}~$${DEVELOPMENT_VERSION}
26}
27
28QMAKE_CXXFLAGS *= \
29    -shared-libgcc \
30    -std=c++11 # replace this by CONFIG += c++11 in Qt5
31QMAKE_CXXFLAGS_DEBUG *= -gdwarf-2 -g3
32QMAKE_LFLAGS += -fvisibility=hidden
33
34INCLUDEPATH *= $$PWD
35
36LIB_PREFIX=lib
37LIB_SUFFIX=
38EXT_STATICLIB=a
39EXT_DYNAMICLIB=so
40win32 {
41    VERSIONS = $$split(VERSION, ".")
42    LIB_PREFIX =
43    LIB_SUFFIX = $$member(VERSIONS, 0)
44    EXT_DYNAMICLIB=dll
45       
46        CONFIG -= console
47}
48
49unix {
50    # Search path for libraries
51    CONFIG(debug, debug|release): QMAKE_RPATHDIR *= lib
52    CONFIG(release, debug|release): QMAKE_RPATHDIR *= /usr/lib/smssender
53}
54
55TRANSLATIONS *= \
56    locale/de.ts \
57    locale/de_CH.ts \
58    locale/fr.ts \
59    locale/it.ts
Note: See TracBrowser for help on using the repository browser.